| wdenk | 2262cfe | 2002-11-18 00:14:45 +0000 | [diff] [blame] | 1 | /* |
| 2 | * (C) Copyright 2002 |
| 3 | * Daniel Engström, Omicron Ceti AB, daniel@omicron.se. |
| 4 | * |
| 5 | * See file CREDITS for list of people who contributed to this |
| 6 | * project. |
| 7 | * |
| 8 | * This program is free software; you can redistribute it and/or |
| 9 | * modify it under the terms of the GNU General Public License as |
| 10 | * published by the Free Software Foundation; either version 2 of |
| 11 | * the License, or (at your option) any later version. |
| 12 | * |
| 13 | * This program is distributed in the hope that it will be useful, |
| 14 | * but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 15 | * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 16 | * GNU General Public License for more details. |
| 17 | * |
| 18 | * You should have received a copy of the GNU General Public License |
| 19 | * along with this program; if not, write to the Free Software |
| 20 | * Foundation, Inc., 59 Temple Place, Suite 330, Boston, |
| 21 | * MA 02111-1307 USA |
| 22 | */ |
| 23 | |
| 24 | OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386") |
| 25 | OUTPUT_ARCH(i386) |
| 26 | ENTRY(_start) |
| 27 | |
| 28 | SECTIONS |
| 29 | { |
| 30 | . = 0x387e0000; /* Where bootcode in the flash is mapped */ |
| 31 | .text : { *(.text); } |
| 32 | |
| 33 | . = ALIGN(4); |
| 34 | .rodata : { *(.rodata) } |
| 35 | |
| 36 | . = 0x400000; /* Ram data segment to use */ |
| 37 | _i386boot_romdata_dest = ABSOLUTE(.); |
| 38 | .data : AT ( LOADADDR(.rodata) + SIZEOF(.rodata) ) { *(.data) } |
| 39 | _i386boot_romdata_start = LOADADDR(.data); |
| 40 | |
| 41 | . = ALIGN(4); |
| 42 | .got : AT ( LOADADDR(.data) + SIZEOF(.data) ) { *(.got) } |
| 43 | _i386boot_romdata_size = SIZEOF(.data) + SIZEOF(.got); |
| 44 | |
| 45 | |
| 46 | . = ALIGN(4); |
| 47 | _i386boot_bss_start = ABSOLUTE(.); |
| 48 | .bss : { *(.bss) } |
| 49 | _i386boot_bss_size = SIZEOF(.bss); |
| 50 | |
| 51 | |
| 52 | /* 16bit realmode trampoline code */ |
| 53 | .realmode 0x7c0 : AT ( LOADADDR(.got) + SIZEOF(.got) ) { *(.realmode) } |
| 54 | |
| 55 | _i386boot_realmode = LOADADDR(.realmode); |
| 56 | _i386boot_realmode_size = SIZEOF(.realmode); |
| 57 | |
| 58 | /* 16bit BIOS emulation code (just enough to boot Linux) */ |
| 59 | .bios 0 : AT ( LOADADDR(.realmode) + SIZEOF(.realmode) ) { *(.bios) } |
| 60 | |
| 61 | _i386boot_bios = LOADADDR(.bios); |
| 62 | _i386boot_bios_size = SIZEOF(.bios); |
| 63 | |
| 64 | |
| 65 | /* The load addresses below assumes that the flash |
| 66 | * will be mapped so that 0x387f0000 == 0xffff0000 |
| 67 | * at reset time |
| 68 | * |
| 69 | * The fe00 and ff00 offsets of the start32 and start16 |
| 70 | * segments are arbitrary, the just have to be mapped |
| 71 | * at reset and the code have to fit. |
| 72 | * The fff0 offset of reset is important, however. |
| 73 | */ |
| 74 | |
| 75 | |
| 76 | . = 0xfffffe00; |
| 77 | .start32 : AT (0x387ffe00) { *(.start32); } |
| 78 | |
| 79 | . = 0xff00; |
| 80 | .start16 : AT (0x387fff00) { *(.start16); } |
| 81 | |
| 82 | . = 0xfff0; |
| 83 | .reset : AT (0x387ffff0) { *(.reset); } |
| 84 | _i386boot_end = (LOADADDR(.reset) + SIZEOF(.reset) ); |
| 85 | } |